home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / sh7x / sh75b.d64 / superfrac 64 (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  2KB  |  78 lines
  1. 1000 REM ****************
  2. 1010 REM * SUPERFRAC 64 *
  3. 1020 REM * VERSION 4.57 *
  4. 1030 REM * VOM 02.07.87 *
  5. 1040 REM * PROGRAMMING: *
  6. 1050 REM * I.CAMPHAUSEN *
  7. 1060 REM ****************
  8. 1070 :
  9. 1080 IF A=0 THEN PRINT"[147]";TAB(13);"MOMENT BITTE!"
  10. 1090 IF A=0 THEN POKE 55,0:POKE 56,142:CLR:A=1:LOAD"MC.SF 64",8,1
  11. 1100 IF A=1 THEN A=2:LOAD"DAT.SF 64",8,1
  12. 1110 :
  13. 1120 REM
  14. 1130 REM **************************
  15. 1140 REM VARIABLE/WICHTIGE ADRESSEN
  16. 1150 REM **************************
  17. 1160 REM
  18. 1170 RU=36396:DI=36413:BE=38985:GI=36607:TA=39494:DR=39510
  19. 1180 NL=39780:DL=39781:DS=39794:GL=39817:GS=39833:DG=36433
  20. 1190 A1(1)=DL:A1(2)=DS:A1(3)=GL:A1(4)=GS
  21. 1200 A2(1)=DI:A2(2)=DG:A2(3)=GIN:A2(4)=DG
  22. 1210 FOR I=1 TO 6:READ AD(I):NEXT I
  23. 1220 DATA 24576,24608,24640,26656,26688,28736
  24. 1230 FOR I=1 TO 4:READ UE$(I):NEXT I
  25. 1240 DATA " DLOAD "," DSAVE "," GLOAD "," GSAVE "
  26. 1250 :
  27. 1260 REM
  28. 1270 REM *************
  29. 1280 REM HAUPTPROGRAMM
  30. 1290 REM *************
  31. 1300 REM
  32. 1310 SYS 36352
  33. 1320 NR=PEEK(BE)-1:IF NR>0 THEN GOSUB 1510:GOTO 1320
  34. 1330 GOSUB 1350:GOTO 1320
  35. 1340 :
  36. 1350 REM
  37. 1360 REM ***************************
  38. 1370 REM UP EINGABE DER STUETZPUNKTE
  39. 1380 REM ***************************
  40. 1390 REM
  41. 1400 PRINT:PRINT
  42. 1410 FOR I=1 TO 6
  43. 1420 :  H=0
  44. 1430 :  PRINT"HOEHE"I"[157]. STUETZPUNKT ";:INPUT H
  45. 1440 :  IF ABS(H)>30 THEN PRINT"BITTE BEACHTEN: -30 <= HOEHE <= +30![146]":GOTO1420
  46. 1450 :  IF H<0 THEN H=256+H
  47. 1460 :  POKE AD(I),H
  48. 1470 NEXT I
  49. 1480 SYS RU
  50. 1490 RETURN
  51. 1500 :
  52. 1510 REM
  53. 1520 REM *******************
  54. 1530 REM UP DISKETTENZUGRIFF
  55. 1540 REM *******************
  56. 1550 REM
  57. 1560 PRINT "[147][144]****************************************"
  58. 1570 PRINT "";TAB((40-LEN(UE$(NR)))/2);UE$(NR)
  59. 1580 N$="":INPUT"FILENAME ";N$
  60. 1590 IF N$="" THEN SYS DG:RETURN
  61. 1600 IF N$="$"THEN SYS DR:GOSUB 1690:IF FE=0 THEN SYS TASTE:GOTO 1560
  62. 1610 IF NR<3 THEN N$=CHR$(4)+N$
  63. 1620 IF NR>2 THEN N$=CHR$(7)+N$
  64. 1630 POKE NL,LEN(N$)
  65. 1640 FOR I=1 TO LEN(N$):POKE 703+I,ASC(MID$(N$,I,1)):NEXT I
  66. 1650 SYS A1(NR):GOSUB 1690:IF FE<>0 THEN 1560
  67. 1660 SYS A2(NR)
  68. 1670 RETURN
  69. 1680 :
  70. 1690 REM
  71. 1700 REM **************
  72. 1710 REM UP FEHLERKANAL
  73. 1720 REM **************
  74. 1730 REM
  75. 1740 OPEN 1,8,15:INPUT#1,FE,FE$,A,B:CLOSE 1                    
  76. 1750 PRINT:PRINT FE,FE$:IF FE<>0 THEN SYS TA
  77. 1760 RETURN
  78.